package preface

  1. Overview
  2. Docs
package preface
Legend:
Page
Library
Module
Module type
Parameter
Class
Class type
Source

Source file foldable.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
module Core_via_fold_right (Req : Preface_specs.Foldable.WITH_FOLD_RIGHT) :
  Preface_specs.Foldable.CORE with type 'a t = 'a Req.t = struct
  include Req

  let fold_map' neutral combine f x =
    let reducer x acc = combine (f x) acc in
    fold_right reducer x neutral
  ;;
end

module Core_via_fold_map (Req : Preface_specs.Foldable.WITH_FOLD_MAP) :
  Preface_specs.Foldable.CORE with type 'a t = 'a Req.t = struct
  include Req

  let fold_right f x acc =
    (fold_map' (fun x -> x) (fun f g x -> f (g x)) f) x acc
  ;;
end

module Operation (C : Preface_specs.Foldable.CORE) :
  Preface_specs.Foldable.OPERATION with type 'a t = 'a C.t = struct
  type 'a t = 'a C.t

  let fold_map (type m) (module M : Preface_specs.Monoid.CORE with type t = m) f
      x =
    C.fold_map' M.neutral M.combine f x
  ;;

  let reduce (type m) (module M : Preface_specs.Monoid.CORE with type t = m) x =
    fold_map (module M) (fun x -> x) x
  ;;

  let fold_left f acc x =
    let f' x k z = k (f z x) in
    let fold = C.fold_right f' x (fun x -> x) in
    fold acc
  ;;

  let for_all p x = C.fold_map' true ( && ) p x

  let exists p x = C.fold_map' false ( || ) p x

  let length x = fold_left (fun acc _ -> succ acc) 0 x
end

module Via
    (C : Preface_specs.Foldable.CORE)
    (O : Preface_specs.Foldable.OPERATION with type 'a t = 'a C.t) :
  Preface_specs.FOLDABLE with type 'a t = 'a O.t = struct
  include C

  include (O : Preface_specs.Foldable.OPERATION with type 'a t := 'a t)
end

module Via_fold_right (Req : Preface_specs.Foldable.WITH_FOLD_RIGHT) :
  Preface_specs.FOLDABLE with type 'a t = 'a Req.t = struct
  module C = Core_via_fold_right (Req)
  module O = Operation (C)
  include Via (C) (O)
end

module Via_fold_map (Req : Preface_specs.Foldable.WITH_FOLD_MAP) :
  Preface_specs.FOLDABLE with type 'a t = 'a Req.t = struct
  module C = Core_via_fold_map (Req)
  module O = Operation (C)
  include Via (C) (O)
end

module Composition (F : Preface_specs.FOLDABLE) (G : Preface_specs.FOLDABLE) :
  Preface_specs.FOLDABLE with type 'a t = 'a G.t F.t = Via_fold_map (struct
  type 'a t = 'a G.t F.t

  let fold_map' neutral combine f x =
    F.fold_map' neutral combine (G.fold_map' neutral combine f) x
  ;;
end)

module Sum (F : Preface_specs.FOLDABLE) (G : Preface_specs.FOLDABLE) = struct
  type 'a sum =
    | L of 'a F.t
    | R of 'a G.t

  include Via_fold_map (struct
    type 'a t = 'a sum

    let fold_map' neutral combine f = function
      | L x -> F.fold_map' neutral combine f x
      | R x -> G.fold_map' neutral combine f x
    ;;
  end)
end

module Product (F : Preface_specs.FOLDABLE) (G : Preface_specs.FOLDABLE) :
  Preface_specs.FOLDABLE with type 'a t = 'a F.t * 'a G.t = Via_fold_map (struct
  type 'a t = 'a F.t * 'a G.t

  let fold_map' neutral combine f (x, y) =
    combine (F.fold_map' neutral combine f x) (G.fold_map' neutral combine f y)
  ;;
end)
OCaml

Innovation. Community. Security.

GitHub Discord Twitter Peertube RSS
About
Changelog Releases Industrial Users Academic Users Why OCaml
Ecosystem
Packages Community Events OCaml Planet Jobs
Resources
Install OCaml Get Started Platform Tools Language Manual Standard Library API Books Exercises Papers OCaml Playground Logo
Policies
Carbon Footprint Governance Privacy Code of Conduct