Source file values.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
(** Abstract representations of values in a vo *)
(** NB: This needs updating when the types in declarations.ml and
their dependencies are changed. *)
(** We reify here the types of values present in a vo.
in order to validate its structure. Maybe this reification
could become automatically generated someday ?
See values.mli for the meaning of each constructor.
*)
type 'v kind =
| Any
| Fail of string
| Tuple of string * 'v array
| Sum of string * int * 'v array array
| Array of 'v
| List of 'v
| Opt of 'v
| Int
| String
| Annot of string * 'v
| Int64
| Float64
module Vector = struct
type ('a,_) t =
| [] : ('a, [`O]) t
| (::) : 'a * ('a, 's) t -> ('a, [`S of 's]) t
type 'n size = (unit,'n) t
let rec vmap : 'n 'a 'b. ('a -> 'b) -> ('a,'n) t -> ('b, 'n) t =
fun (type n) f (v:(_,n) t) : (_,n) t ->
match v with
| [] -> []
| x :: tl ->
let x = f x in
x :: vmap f tl
let rec viter2 : 'n 'a 'b. ('a -> 'b -> unit) -> ('a,'n) t -> ('b,'n) t -> unit =
fun (type n) f (v1:(_,n) t) (v2:(_,n) t) ->
match v1, v2 with
| [], []-> ()
| x1 :: tl1, x2 :: tl2 ->
let () = f x1 x2 in
viter2 f tl1 tl2
end
module Internal : sig
type value
val equal : value -> value -> bool
val kind : value -> value kind
val of_kind : value kind -> value
val mfix : 'n Vector.size -> ((value,'n) Vector.t -> (value,'n) Vector.t) -> (value,'n) Vector.t
end = struct
type value =
| V of value kind
| Proxy of value kind ref
let kind = function
| V v -> v
| Proxy v -> !v
let equal a b = kind a == kind b
let of_kind v = V v
let check_productive = function
| Proxy _ -> assert false
| V v -> v
let mfix (type n) (n:n Vector.size) (f : (value,n) Vector.t -> (value,n) Vector.t) : (value,n) Vector.t =
let open Vector in
let self = vmap (fun () -> Proxy (ref Any)) n in
let ans = f self in
let () = viter2 (fun self ans ->
let ans = check_productive ans in
match self with
| Proxy self -> self := ans
| _ -> assert false)
self ans
in
ans
end
type nonrec value = Internal.value
let equal = Internal.equal
let kind = Internal.kind
let of_kind = Internal.of_kind
let mfix = Internal.mfix
let fix f =
let [v] : _ Vector.t = mfix [()] (fun [v] -> [f v]) in
v
(** Some pseudo-constructors *)
let v_tuple name v = of_kind @@ Tuple(name,v)
let v_sum name cc vv = of_kind @@ Sum(name,cc,vv)
let v_enum name n = of_kind @@ Sum(name,n,[||])
let v_annot a v = of_kind @@ Annot (a, v)
let v_fail f = of_kind @@ Fail f
let v_tuple_c (name,v) = v_tuple name v
let v_sum_c (name,cc,vv) = v_sum name cc vv
let v_annot_c (a, v) = v_annot a v
(** Ocaml standard library *)
let v_any = of_kind Any
let v_int = of_kind Int
let v_int64 = of_kind Int64
let v_float64 = of_kind Float64
let v_string = of_kind String
let v_opt v = of_kind @@ Opt v
let v_list v = of_kind @@ List v
let v_array v = of_kind @@ Array v
let v_pair v1 v2 = v_tuple "*" [|v1; v2|]
let v_bool = v_enum "bool" 2
let v_unit = v_enum "unit" 1
let v_set v =
fix (fun s ->
v_sum_c ("Set.t",1,
[|[|s; v_annot_c ("elem", v); s; v_annot_c ("bal", v_int)|]|]))
let v_map vk vd =
fix (fun m ->
v_sum_c ("Map.t",1,
[|[|m; v_annot_c("key",vk); v_annot_c("data",vd); m; v_annot_c("bal",v_int)|]|]))
let v_hset v = v_map v_int (v_set v)
let v_hmap vk vd = v_map v_int (v_map vk vd)
let v_pred v = v_pair v_bool (v_set v)
(** kernel/names *)
let v_id = v_string
let v_dp = v_annot_c ("dirpath", v_list v_id)
let v_name = v_sum "name" 1 [|[|v_id|]|]
let v_uid = v_tuple "uniq_ident" [|v_int;v_string;v_dp|]
let v_mp =
fix (fun v_mp ->
v_sum_c("module_path",0,
[|[|v_dp|];
[|v_uid|];
[|v_mp;v_id|]|]))
let v_kn = v_tuple "kernel_name" [|v_mp;v_id;v_int|]
let v_cst = v_sum "cst|mind" 0 [|[|v_kn|];[|v_kn;v_kn|]|]
let v_ind = v_tuple "inductive" [|v_cst;v_int|]
let v_cons = v_tuple "constructor" [|v_ind;v_int|]
(** kernel/univ *)
let v_level_global = v_tuple "Level.Global.t" [|v_dp;v_string;v_int|]
let v_raw_level = v_sum "raw_level" 1
[|[|v_level_global|]; [|v_int|]|]
let v_level = v_tuple "level" [|v_int;v_raw_level|]
let v_expr = v_tuple "levelexpr" [|v_level;v_int|]
let v_univ = v_list v_expr
let v_qvar = v_sum "qvar" 0 [|[|v_int|];[|v_string;v_int|]|]
let v_constant_quality = v_enum "constant_quality" 3
let v_quality = v_sum "quality" 0 [|[|v_qvar|];[|v_constant_quality|]|]
let v_cstrs =
v_annot_c
("Univ.constraints",
v_set
(v_tuple "univ_constraint"
[|v_level;v_enum "order_request" 3;v_level|]))
let v_variance = v_enum "variance" 3
let v_instance = v_annot_c ("instance", v_pair (v_array v_quality) (v_array v_level))
let v_abs_context = v_tuple "abstract_universe_context" [|v_pair (v_array v_name) (v_array v_name); v_cstrs|]
let v_context_set = v_tuple "universe_context_set" [|v_hset v_level;v_cstrs|]
(** kernel/term *)
let v_sort = v_sum "sort" 3 [|[|v_univ|];[|v_qvar;v_univ|]|]
let v_relevance = v_sum "relevance" 2 [|[|v_qvar|]|]
let v_binder_annot x = v_tuple "binder_annot" [|x;v_relevance|]
let v_puniverses v = v_tuple "punivs" [|v;v_instance|]
let v_caseinfo =
let v_cstyle = v_enum "case_style" 5 in
let v_cprint = v_tuple "case_printing" [|v_cstyle|] in
v_tuple "case_info" [|v_ind;v_int;v_array v_int;v_array v_int;v_cprint|]
let v_cast = v_enum "cast_kind" 3
let v_proj_repr = v_tuple "projection_repr" [|v_ind;v_int;v_int;v_cst|]
let v_proj = v_tuple "projection" [|v_proj_repr; v_bool|]
let v_uint63 =
if Sys.word_size == 64 then v_int else v_int64
let v_constr =
fix (fun v_constr ->
let v_prec =
v_tuple_c ("prec_declaration",
[|v_array (v_binder_annot v_name); v_array v_constr; v_array v_constr|])
in
let v_fix = v_tuple_c ("pfixpoint", [|v_tuple_c ("fix2",[|v_array v_int;v_int|]);v_prec|]) in
let v_cofix = v_tuple_c ("pcofixpoint",[|v_int;v_prec|]) in
let v_case_invert = v_sum_c ("case_inversion", 1, [|[|v_array v_constr|]|]) in
let v_case_branch = v_tuple_c ("case_branch", [|v_array (v_binder_annot v_name); v_constr|]) in
let v_case_return = v_tuple_c ("case_return", [|v_tuple_c ("case_return'", [|v_array (v_binder_annot v_name); v_constr|]); v_relevance|]) in
v_sum_c ("constr",0,[|
[|v_int|];
[|v_id|];
[|v_fail "Meta"|];
[|v_fail "Evar"|];
[|v_sort|];
[|v_constr;v_cast;v_constr|];
[|v_binder_annot v_name;v_constr;v_constr|];
[|v_binder_annot v_name;v_constr;v_constr|];
[|v_binder_annot v_name;v_constr;v_constr;v_constr|];
[|v_constr;v_array v_constr|];
[|v_puniverses v_cst|];
[|v_puniverses v_ind|];
[|v_puniverses v_cons|];
[|v_caseinfo;v_instance; v_array v_constr; v_case_return; v_case_invert; v_constr; v_array v_case_branch|];
[|v_fix|];
[|v_cofix|];
[|v_proj;v_relevance;v_constr|];
[|v_uint63|];
[|v_float64|];
[|v_string|];
[|v_instance;v_array v_constr;v_constr;v_constr|]
|]))
let v_rdecl = v_sum "rel_declaration" 0
[| [|v_binder_annot v_name; v_constr|];
[|v_binder_annot v_name; v_constr; v_constr|] |]
let v_rctxt = v_list v_rdecl
let v_ndecl = v_sum "named_declaration" 0
[| [|v_binder_annot v_id; v_constr|];
[|v_binder_annot v_id; v_constr; v_constr|] |]
let v_nctxt = v_list v_ndecl
let v_section_ctxt = v_enum "emptylist" 1
(** kernel/mod_subst *)
let v_univ_abstracted v = v_tuple "univ_abstracted" [|v;v_abs_context|]
let v_delta_hint =
v_sum "delta_hint" 0 [|[|v_int; v_opt (v_univ_abstracted v_constr)|];[|v_kn|]|]
let v_resolver =
v_tuple "delta_resolver"
[|v_map v_mp v_mp;
v_hmap v_kn v_delta_hint|]
let v_mp_resolver = v_tuple "" [|v_mp;v_resolver|]
let v_subst =
v_annot_c ("substitution", v_map v_mp v_mp_resolver)
(** kernel/lazyconstr *)
let v_abstr_info =
v_tuple_c ("abstr_info", [|v_nctxt; v_abs_context; v_instance|])
let v_abstr_inst_info =
v_tuple_c ("abstr_inst_info", [|v_list v_id; v_instance|])
let v_expand_info =
v_tuple_c ("expand_info", [|v_hmap v_cst v_abstr_inst_info; v_hmap v_cst v_abstr_inst_info|])
let v_cooking_info =
v_tuple_c ("cooking_info", [|v_expand_info; v_abstr_info|])
let v_opaque =
v_sum "opaque" 0 [|[|v_list v_subst; v_list v_cooking_info; v_dp; v_int|]|]
(** kernel/declarations *)
let v_conv_level =
v_sum "conv_level" 2 [|[|v_int|]|]
let v_oracle =
v_tuple "oracle" [|
v_map v_id v_conv_level;
v_hmap v_cst v_conv_level;
v_hmap v_proj_repr v_conv_level;
v_pred v_id;
v_pred v_cst;
v_pred v_proj_repr;
|]
let v_template_arity =
v_tuple "template_arity" [|v_sort|]
let v_template_universes =
v_tuple "template_universes" [|v_list v_bool;v_context_set|]
let v_primitive =
v_enum "primitive" 63
let v_cst_def =
v_sum "constant_def" 0
[|[|v_opt v_int|]; [|v_constr|]; [|v_opaque|]; [|v_primitive|]; [|v_bool|]|]
let v_typing_flags =
v_tuple "typing_flags"
[|v_bool; v_bool; v_bool;
v_oracle; v_bool; v_bool;
v_bool; v_bool; v_bool; v_bool; v_bool|]
let v_univs = v_sum "universes" 1 [|[|v_abs_context|]|]
let v_vm_reloc_table = v_array (v_pair v_int v_int)
let v_vm_annot_switch = v_tuple "vm_annot_switch" [|v_vm_reloc_table; v_bool; v_int|]
let v_vm_caml_prim = v_enum "vm_caml_prim" 6
let v_non_subst_reloc = v_sum "vm_non_subst_reloc" 0 [|
[|v_sort|];
[|v_fail "Evar"|];
[|v_int|];
[|v_instance|];
[|v_any|];
[|v_uint63|];
[|v_float64|];
[|v_string|];
[|v_vm_annot_switch|];
[|v_vm_caml_prim|];
|]
let v_reloc = v_sum "vm_reloc" 0 [|
[|v_ind|];
[|v_cst|];
[|v_int|];
|]
let v_vm_patches = v_tuple "vm_patches" [|v_array v_reloc|]
let v_vm_pbody_code index =
v_sum "pbody_code" 1 [|
[|v_array v_bool; index; v_vm_patches|];
[|v_cst|];
|]
let v_vm_index = v_pair v_dp v_int
let v_vm_indirect_code = v_vm_pbody_code v_vm_index
let v_vm_emitcodes = v_string
let v_vm_fv_elem = v_sum "vm_fv_elem" 0 [|
[|v_id|];
[|v_int|]
|]
let v_vm_fv = v_array v_vm_fv_elem
let v_vm_positions = v_string
let v_vm_to_patch = v_tuple "vm_to_patch" [|v_vm_emitcodes; v_vm_fv; v_vm_positions; v_array v_non_subst_reloc|]
let v_cb = v_tuple "constant_body"
[|v_section_ctxt;
v_instance;
v_cst_def;
v_constr;
v_relevance;
v_opt v_vm_indirect_code;
v_univs;
v_bool;
v_typing_flags|]
let v_recarg_type = v_sum "recarg_type" 0
[|[|v_ind|] ;[|v_cst|] |]
let v_recarg = v_sum "recarg" 1
[|[|v_recarg_type|] |]
let v_wfp =
fix (fun v_wfp ->
v_sum_c ("wf_paths",0,
[|[|v_int;v_int|];
[|v_recarg;v_array (v_array v_wfp)|];
[|v_int;v_array v_wfp|]
|]))
let v_mono_ind_arity =
v_tuple "monomorphic_inductive_arity" [|v_constr;v_sort|]
let v_ind_arity = v_sum "inductive_arity" 0
[|[|v_mono_ind_arity|];[|v_template_arity|]|]
let v_squash_info = v_sum "squash_info" 1 [|[|v_set v_quality|]|]
let v_one_ind = v_tuple "one_inductive_body"
[|v_id;
v_rctxt;
v_ind_arity;
v_array v_id;
v_array v_constr;
v_int;
v_int;
v_opt v_squash_info;
v_array (v_pair v_rctxt v_constr);
v_array v_int;
v_array v_int;
v_wfp;
v_relevance;
v_int;
v_int;
v_vm_reloc_table|]
let v_finite = v_enum "recursivity_kind" 3
let v_record_info =
v_sum "record_info" 2
[| [| v_array (v_tuple "record" [| v_id; v_array v_id; v_array v_relevance; v_array v_constr |]) |] |]
let v_ind_pack = v_tuple "mutual_inductive_body"
[|v_array v_one_ind;
v_record_info;
v_finite;
v_int;
v_section_ctxt;
v_instance;
v_int;
v_int;
v_rctxt;
v_univs;
v_opt v_template_universes;
v_opt (v_array v_variance);
v_opt (v_array v_variance);
v_opt v_bool;
v_typing_flags|]
let v_prim_ind = v_enum "prim_ind" 6
let v_prim_type = v_enum "prim_type" 4
let v_retro_action =
v_sum "retro_action" 0 [|
[|v_prim_ind; v_ind|];
[|v_prim_type; v_cst|];
|]
let v_retroknowledge =
v_sum "module_retroknowledge" 0 [|[|v_list v_retro_action|]|]
let v_puniv = v_opt v_int
let v_pqvar = v_opt v_int
let v_quality_pattern = v_sum "quality_pattern" 0 [|[|v_pqvar|];[|v_constant_quality|]|]
let v_instance_mask = v_pair (v_array v_quality_pattern) (v_array v_puniv)
let v_sort_pattern = v_sum_c ("sort_pattern", 3,
[|[|v_puniv|];
[|v_pqvar; v_puniv|]
|])
let [_v_hpattern;v_elimination;_v_head_elim;_v_patarg] : _ Vector.t =
mfix [();();();()] (fun [v_hpattern;v_elimination;v_head_elim;v_patarg] ->
let v_hpattern =
v_sum_c ("head_pattern", 0,
[|[|v_int|];
[|v_sort_pattern|];
[|v_cst; v_instance_mask|];
[|v_ind; v_instance_mask|];
[|v_cons; v_instance_mask|];
[|v_uint63|];
[|v_float64|];
[|v_string|];
[|v_array v_patarg; v_patarg|];
[|v_array v_patarg; v_patarg|];
|])
and v_elimination =
v_sum_c ("pattern_elimination", 0,
[|[|v_array v_patarg|];
[|v_ind; v_instance_mask; v_patarg; v_array v_patarg|];
[|v_proj|];
|])
and v_head_elim = v_tuple_c ("head*elims", [|v_hpattern; v_list v_elimination|])
and v_patarg =
v_sum_c ("pattern_argument", 1,
[|[|v_int|];
[|v_head_elim|];
|])
in
[v_hpattern;v_elimination;v_head_elim;v_patarg])
let v_rewrule = v_tuple "rewrite_rule"
[| v_tuple "nvars" [| v_int; v_int; v_int |]; v_pair v_instance_mask (v_list v_elimination); v_constr |]
let v_rrb = v_tuple "rewrite_rules_body"
[| v_list (v_pair v_cst v_rewrule) |]
let v_module_with_decl = v_sum "with_declaration" 0 [|
[|v_list v_id; v_mp|];
[|v_list v_id; v_pair v_constr (v_opt v_abs_context)|];
|]
let v_mae =
fix (fun v_mae ->
v_sum_c ("module_alg_expr",0,
[|[|v_mp|];
[|v_mae;v_mp|];
[|v_mae; v_module_with_decl|]
|]))
let [_v_sfb;_v_struc;_v_sign;_v_mexpr;_v_impl;v_module;_v_modtype] : _ Vector.t =
mfix [();();();();();();()] (fun [v_sfb;v_struc;v_sign;v_mexpr;v_impl;v_module;v_modtype] ->
let v_noimpl = v_unit in
let v_sfb =
v_sum_c ("struct_field_body",0,
[|[|v_cb|];
[|v_ind_pack|];
[|v_rrb|];
[|v_module|];
[|v_modtype|]
|])
and v_struc = v_list (v_tuple_c ("label*sfb",[|v_id;v_sfb|]))
and v_sign =
v_sum_c ("module_sign",0,
[|[|v_struc|];
[|v_uid;v_modtype;v_sign|]|])
and v_mexpr =
v_sum_c ("module_expr",0,
[|[|v_mae|];
[|v_mexpr|]|])
and v_impl =
v_sum_c ("module_impl",2,
[|[|v_mexpr|];
[|v_struc|]|])
and v_module =
v_tuple_c ("module_body",
[|v_mp;v_sum_c ("when_mod_body", 0, [|[|v_impl|]|]);v_sign;v_opt v_mexpr;v_resolver;v_retroknowledge|])
and v_modtype =
v_tuple_c ("module_type_body",
[|v_mp;v_noimpl;v_sign;v_opt v_mexpr;v_resolver;v_unit|])
in
[v_sfb;v_struc;v_sign;v_mexpr;v_impl;v_module;v_modtype])
(** kernel/safe_typing *)
let v_vodigest = v_sum_c ("module_impl",0, [| [|v_string|]; [|v_string;v_string|] |])
let v_deps = v_array (v_tuple "dep" [|v_dp;v_vodigest|])
let v_flags = v_tuple "flags" [|v_bool|]
let v_compiled_lib =
v_tuple "compiled" [|v_dp;v_module;v_context_set;v_deps; v_flags|]
(** Toplevel structures in a vo (see Cic.mli) *)
let v_libsum =
v_tuple_c ("summary", [|v_dp;v_deps;v_string;v_any|])
let v_lib =
v_tuple_c ("library",[|v_compiled_lib;v_any;v_any|])
let v_delayed_universes =
v_sum_c ("delayed_universes", 0, [| [| v_unit |]; [| v_context_set |] |])
let v_opaquetable = v_array (v_opt (v_pair v_constr v_delayed_universes))
let v_vmlib = v_tuple "vmlibrary" [|v_dp; v_array v_vm_to_patch|]