Source file apply.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
open Preface_core.Fun
module Core_via_map_and_apply (Req : Preface_specs.Apply.WITH_MAP_AND_APPLY) =
struct
include Req
let product a b = apply (map (fun a b -> (a, b)) a) b
let lift2 f x y = apply (map f x) y
end
module Core_over_functor_via_apply
(Functor : Preface_specs.Functor.WITH_MAP)
(Req : Preface_specs.Apply.WITH_APPLY with type 'a t = 'a Functor.t) =
struct
include Core_via_map_and_apply (struct
include Functor
include Req
end)
end
module Core_via_map_and_product (Req : Preface_specs.Apply.WITH_MAP_AND_PRODUCT) =
struct
include Req
let apply f a = map (fun (f, a) -> f a) @@ product f a
let lift2 f x y = apply (map f x) y
end
module Core_over_functor_via_product
(Functor : Preface_specs.Functor.WITH_MAP)
(Req : Preface_specs.Apply.WITH_PRODUCT with type 'a t = 'a Functor.t) =
struct
include Core_via_map_and_product (struct
include Functor
include Req
end)
end
module Core_via_map_and_lift2 (Req : Preface_specs.Apply.WITH_MAP_AND_LIFT2) =
struct
include Req
let apply f a = lift2 (fun x -> x) f a
let product a b = apply (map (fun a b -> (a, b)) a) b
end
module Core_over_functor_via_lift2
(Functor : Preface_specs.Functor.WITH_MAP)
(Req : Preface_specs.Apply.WITH_LIFT2 with type 'a t = 'a Functor.t) =
struct
include Core_via_map_and_lift2 (struct
include Functor
include Req
end)
end
module Operation (Core : Preface_specs.Apply.CORE) = struct
include Functor.Operation (Core)
let lift = Core.map
let lift3 f a b = Core.(apply @@ apply (Core.map f a) b)
end
module Syntax (Core : Preface_specs.Apply.CORE) = struct
type 'a t = 'a Core.t
let ( let+ ) x f = Core.map f x
let ( and+ ) = Core.product
end
module Infix
(Core : Preface_specs.Apply.CORE)
(Operation : Preface_specs.Apply.OPERATION with type 'a t = 'a Core.t) =
struct
include Functor.Infix (Core) (Operation)
let ( <*> ) = Core.apply
let ( <**> ) a b = Core.lift2 (fun x f -> f x) a b
let ( *> ) a b = Core.lift2 (flip const) a b
let ( <* ) a b = Core.lift2 const a b
end
module Via
(Core : Preface_specs.Apply.CORE)
(Operation : Preface_specs.Apply.OPERATION)
(Infix : Preface_specs.Apply.INFIX)
(Syntax : Preface_specs.Apply.SYNTAX) =
struct
include Core
include Operation
include Syntax
include Infix
module Infix = Infix
module Syntax = Syntax
end
module Via_map_and_apply (Req : Preface_specs.Apply.WITH_MAP_AND_APPLY) = struct
module Core = Core_via_map_and_apply (Req)
module Operation = Operation (Core)
module Syntax = Syntax (Core)
module Infix = Infix (Core) (Operation)
include Core
include Operation
include Syntax
include Infix
end
module Via_map_and_product (Req : Preface_specs.Apply.WITH_MAP_AND_PRODUCT) =
struct
module Core = Core_via_map_and_product (Req)
module Operation = Operation (Core)
module Syntax = Syntax (Core)
module Infix = Infix (Core) (Operation)
include Core
include Operation
include Syntax
include Infix
end
module Via_map_and_lift2 (Req : Preface_specs.Apply.WITH_MAP_AND_LIFT2) = struct
module Core = Core_via_map_and_lift2 (Req)
module Operation = Operation (Core)
module Syntax = Syntax (Core)
module Infix = Infix (Core) (Operation)
include Core
include Operation
include Syntax
include Infix
end
module Over_functor_via_apply
(Functor : Preface_specs.Functor.WITH_MAP)
(Req : Preface_specs.Apply.WITH_APPLY with type 'a t = 'a Functor.t) =
struct
module Core = Core_over_functor_via_apply (Functor) (Req)
module Operation = Operation (Core)
module Syntax = Syntax (Core)
module Infix = Infix (Core) (Operation)
include Core
include Operation
include Syntax
include Infix
end
module Over_functor_via_product
(Functor : Preface_specs.Functor.WITH_MAP)
(Req : Preface_specs.Apply.WITH_PRODUCT with type 'a t = 'a Functor.t) =
struct
module Core = Core_over_functor_via_product (Functor) (Req)
module Operation = Operation (Core)
module Syntax = Syntax (Core)
module Infix = Infix (Core) (Operation)
include Core
include Operation
include Syntax
include Infix
end
module Over_functor_via_lift2
(Functor : Preface_specs.Functor.WITH_MAP)
(Req : Preface_specs.Apply.WITH_LIFT2 with type 'a t = 'a Functor.t) =
struct
module Core = Core_over_functor_via_lift2 (Functor) (Req)
module Operation = Operation (Core)
module Syntax = Syntax (Core)
module Infix = Infix (Core) (Operation)
include Core
include Operation
include Syntax
include Infix
end
module From_bind (Bind : Preface_specs.Bind.CORE) = struct
include Via_map_and_product (struct
type 'a t = 'a Bind.t
let map = Bind.map
let product a b = Bind.(bind (fun a -> map (fun b -> (a, b)) b) a)
end)
end
module From_monad (Monad : Preface_specs.MONAD) = struct
include From_bind (Monad)
end
module From_applicative (Applicative : Preface_specs.APPLICATIVE) = Applicative
module From_alternative (Alternative : Preface_specs.ALTERNATIVE) = Alternative
module Composition (F : Preface_specs.APPLY) (G : Preface_specs.APPLY) =
Over_functor_via_apply
(struct
type 'a t = 'a G.t F.t
let map f x = F.map (G.map f) x
end)
(struct
type 'a t = 'a G.t F.t
let apply f x = F.lift2 G.apply f x
end)
module From_arrow (A : Preface_specs.ARROW) =
Over_functor_via_apply
(struct
type 'a t = (unit, 'a) A.t
let map f x = A.(x >>> arrow f)
end)
(struct
type 'a t = (unit, 'a) A.t
let uncurry f (x, y) = f x y
let apply f x = A.(f &&& x >>> arrow (uncurry Fun.id))
end)
module Product (F : Preface_specs.APPLY) (G : Preface_specs.APPLY) =
Over_functor_via_apply
(struct
type 'a t = 'a F.t * 'a G.t
let map f (x, y) = (F.map f x, G.map f y)
end)
(struct
type 'a t = 'a F.t * 'a G.t
let apply (f, g) (x, y) = (F.apply f x, G.apply g y)
end)
module Const (M : Preface_specs.Monoid.CORE) = struct
type 'a t = Const of M.t
include (
Over_functor_via_apply
(struct
type nonrec 'a t = 'a t
let map _f (Const x) = Const x
end)
(struct
type nonrec 'a t = 'a t
let apply (Const f) (Const x) = Const (M.combine f x)
end) :
Preface_specs.APPLY with type 'a t := 'a t )
let get (Const value) = value
end