Source file eval.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
open! Core
open! Import
open Incr.Let_syntax
let unusable_static_apply_action
~inject_dynamic:_
~inject_static:_
~schedule_event:_
_model
=
Nothing.unreachable_code
;;
let unusable_dynamic_apply_action
~inject_dynamic:_
~inject_static:_
~schedule_event:_
_input
_model
=
Nothing.unreachable_code
;;
let () = Incr.State.(set_max_height_allowed t 1024)
let do_nothing_lifecycle : Lifecycle.t Path.Map.t Incr.t =
Incr.return Lifecycle.Collection.empty
;;
let raise_duplicate_path path =
raise_s
[%message
"BUG: [Bonsai.Path.t] should be unique for all components, but duplicate paths \
were discovered."
(path : Path.t)]
;;
let merge_lifecycles
: Lifecycle.Collection.t Incr.t -> Lifecycle.Collection.t Incr.t
-> Lifecycle.Collection.t Incr.t
=
fun a b ->
Incr_map.merge a b ~f:(fun ~key -> function
| `Both _ -> raise_duplicate_path key
| `Left a -> Some a
| `Right a -> Some a)
;;
let unzip3_mapi' map ~f =
let first, second_and_third =
Incr_map.unzip_mapi' map ~f:(fun ~key ~data ->
let a, b, c = f ~key ~data in
let bc = Incr.both b c in
annotate Lifecycle_apply_action_pair bc;
a, bc)
in
let second, third = Incr_map.unzip second_and_third in
first, second, third
;;
let unit_model = Incr.return ()
let rec gather : type result. result Computation.t -> result Computation.packed_info =
let open Computation in
function
| Return value ->
let run ~environment ~path:_ ~clock:_ ~model:_ ~inject_dynamic:_ ~inject_static:_ =
let result = Value.eval environment value in
Snapshot.create ~result ~input:Input.static ~lifecycle:None
in
T
{ model = Meta.Model.unit
; input = Meta.Input.unit
; dynamic_action = Meta.Action.nothing
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset = reset_unit_model
; run
}
| Leaf01
{ model
; input_id
; dynamic_action
; static_action
; apply_dynamic
; apply_static
; reset
; input
} ->
let run ~environment ~path:_ ~clock:_ ~model ~inject_dynamic ~inject_static =
let input = Value.eval environment input in
let result =
let%mapn model = model in
model, inject_dynamic, inject_static
in
Snapshot.create ~result ~input:(Input.dynamic input) ~lifecycle:None
in
T
{ model
; input = input_id
; dynamic_action
; static_action
; apply_static
; apply_dynamic
; reset
; run
}
| Leaf1 { model; input_id; dynamic_action; apply_action; input; reset } ->
let run ~environment ~path:_ ~clock:_ ~model ~inject_dynamic ~inject_static:_ =
let input = Value.eval environment input in
let result =
let%mapn model = model in
model, inject_dynamic
in
Snapshot.create ~result ~input:(Input.dynamic input) ~lifecycle:None
in
T
{ model
; input = input_id
; dynamic_action
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = apply_action
; reset
; run
}
| Leaf0 { model; static_action; apply_action; reset } ->
let run ~environment:_ ~path:_ ~clock:_ ~model ~inject_dynamic:_ ~inject_static =
let result =
let%map model = model in
model, inject_static
in
Snapshot.create ~result ~input:Input.static ~lifecycle:None
in
T
{ model
; input = Meta.Input.unit
; dynamic_action = Meta.Action.nothing
; static_action
; apply_static = apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset
; run
}
| Leaf_incr { input; input_id; compute } ->
let run ~environment ~path:_ ~clock ~model:_ ~inject_dynamic:_ ~inject_static:_ =
let input = Value.eval environment input in
let result = compute clock input in
Snapshot.create ~result ~input:(Input.dynamic input) ~lifecycle:None
in
T
{ model = Meta.Model.unit
; input = input_id
; dynamic_action = Meta.Action.nothing
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset = reset_unit_model
; run
}
| Sub { from; via; into; here } ->
let (T info_from) = gather from in
let (T info_into) = gather into in
let from_stateless, into_stateless =
let same_model = Meta.Model.Type_id.same_witness in
let same_action = Meta.Action.Type_id.same_witness in
let open Option.Let_syntax in
let from_stateless =
let%bind a = same_model info_from.model.type_id Meta.Model.unit.type_id in
let%bind b = same_action info_from.dynamic_action Meta.Action.nothing in
let%bind c = same_action info_from.static_action Meta.Action.nothing in
Some (a, b, c)
in
match from_stateless with
| Some from_stateless -> Some from_stateless, None
| None ->
let into_stateless =
let%bind a = same_model info_into.model.type_id Meta.Model.unit.type_id in
let%bind b = same_action info_into.dynamic_action Meta.Action.nothing in
let%bind c = same_action info_into.static_action Meta.Action.nothing in
Some (a, b, c)
in
None, into_stateless
in
(match from_stateless, into_stateless with
| Some (T, T, T), _ ->
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let from =
let path = Path.append path Path.Elem.Subst_from in
info_from.run
~environment
~path
~clock
~model:unit_model
~inject_dynamic:Nothing.unreachable_code
~inject_static:Nothing.unreachable_code
in
Snapshot.attribute_positions here from;
let from_result = Snapshot.result from in
let environment = Environment.add_exn environment ~key:via ~data:from_result in
let into =
let path = Path.append path Path.Elem.Subst_into in
info_into.run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static
in
let result = Snapshot.result into in
let lifecycle =
Option.merge
(Snapshot.lifecycle from)
(Snapshot.lifecycle into)
~f:merge_lifecycles
in
let input = Snapshot.input into in
Snapshot.create ~result ~input ~lifecycle
in
T
{ run
; input = info_into.input
; model = info_into.model
; dynamic_action = info_into.dynamic_action
; static_action = info_into.static_action
; apply_static = info_into.apply_static
; apply_dynamic = info_into.apply_dynamic
; reset = info_into.reset
}
| _, Some (T, T, T) ->
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let from =
let path = Path.append path Path.Elem.Subst_from in
info_from.run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static
in
Snapshot.attribute_positions here from;
let from_result = Snapshot.result from in
let environment = Environment.add_exn environment ~key:via ~data:from_result in
let into =
let path = Path.append path Path.Elem.Subst_into in
info_into.run
~environment
~path
~clock
~model:unit_model
~inject_dynamic:Nothing.unreachable_code
~inject_static:Nothing.unreachable_code
in
let result = Snapshot.result into in
let lifecycle =
Option.merge
(Snapshot.lifecycle from)
(Snapshot.lifecycle into)
~f:merge_lifecycles
in
let input = Snapshot.input from in
Snapshot.create ~result ~input ~lifecycle
in
T
{ run
; input = info_from.input
; model = info_from.model
; dynamic_action = info_from.dynamic_action
; static_action = info_from.static_action
; apply_static = info_from.apply_static
; apply_dynamic = info_from.apply_dynamic
; reset = info_from.reset
}
| None, None ->
let reset ~inject_dynamic ~inject_static ~schedule_event (model_from, model_into) =
let model_from =
let inject_static action = inject_static (First action) in
let inject_dynamic action = inject_dynamic (First action) in
info_from.reset ~inject_dynamic ~inject_static ~schedule_event model_from
in
let model_into =
let inject_static action = inject_static (Second action) in
let inject_dynamic action = inject_dynamic (Second action) in
info_into.reset ~inject_dynamic ~inject_static ~schedule_event model_into
in
model_from, model_into
in
let apply_static
~inject_dynamic
~inject_static
~schedule_event
(model_from, model_into)
= function
| First action ->
let inject_static action = inject_static (First action) in
let inject_dynamic action = inject_dynamic (First action) in
let model_from =
info_from.apply_static
~inject_dynamic
~inject_static
~schedule_event
model_from
action
in
model_from, model_into
| Second action ->
let inject_static action = inject_static (Second action) in
let inject_dynamic action = inject_dynamic (Second action) in
let model_into =
info_into.apply_static
~inject_dynamic
~inject_static
~schedule_event
model_into
action
in
model_from, model_into
in
let apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
(model_from, model_into)
= function
| First action ->
let inject_static action = inject_static (First action) in
let inject_dynamic action = inject_dynamic (First action) in
let model_from =
info_from.apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
(Option.map input ~f:fst)
model_from
action
in
model_from, model_into
| Second action ->
let inject_static action = inject_static (Second action) in
let inject_dynamic action = inject_dynamic (Second action) in
let model_into =
info_into.apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
(Option.map input ~f:snd)
model_into
action
in
model_from, model_into
in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let from =
let inject_dynamic effect = inject_dynamic (First effect) in
let inject_static effect = inject_static (First effect) in
let model = Incr.map model ~f:Tuple2.get1 in
let path = Path.append path Path.Elem.Subst_from in
info_from.run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static
in
Snapshot.attribute_positions here from;
let from_result = Snapshot.result from in
let environment = Environment.add_exn environment ~key:via ~data:from_result in
let into =
let inject_dynamic effect = inject_dynamic (Second effect) in
let inject_static effect = inject_static (Second effect) in
let model = Incr.map model ~f:Tuple2.get2 in
let path = Path.append path Path.Elem.Subst_into in
info_into.run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static
in
let result = Snapshot.result into in
let lifecycle =
Option.merge
(Snapshot.lifecycle from)
(Snapshot.lifecycle into)
~f:merge_lifecycles
in
let input = Input.merge (Snapshot.input from) (Snapshot.input into) in
Snapshot.create ~result ~input ~lifecycle
in
let model = Meta.Model.both info_from.model info_into.model in
let dynamic_action =
Meta.Action.both info_from.dynamic_action info_into.dynamic_action
in
let static_action =
Meta.Action.both info_from.static_action info_into.static_action
in
let input = Meta.Input.both info_from.input info_into.input in
T
{ model
; input
; dynamic_action
; static_action
; apply_static
; apply_dynamic
; run
; reset
})
| Store { id; value; inner } ->
let (T gathered) = gather inner in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let value = Value.eval environment value in
let environment = Environment.add_overwriting environment ~key:id ~data:value in
gathered.run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static
in
T
{ run
; input = gathered.input
; model = gathered.model
; static_action = gathered.static_action
; dynamic_action = gathered.dynamic_action
; apply_static = gathered.apply_static
; apply_dynamic = gathered.apply_dynamic
; reset = gathered.reset
}
| Fetch { id; default; for_some } ->
let run ~environment ~path:_ ~clock:_ ~model:_ ~inject_dynamic:_ ~inject_static:_ =
let result =
match Environment.find environment id with
| None -> Incr.return default
| Some x -> Incr.map x ~f:(fun a -> for_some a)
in
Snapshot.create ~result ~lifecycle:None ~input:Input.static
in
T
{ model = Meta.Model.unit
; input = Meta.Input.unit
; dynamic_action = Meta.Action.nothing
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset = reset_unit_model
; run
}
| Assoc { map; key_comparator; key_id; cmp_id; data_id; by } ->
let (T
{ model = model_info
; input = input_info
; dynamic_action
; static_action
; apply_static
; apply_dynamic
; run
; reset
})
=
gather by
in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let map_input = Value.eval environment map in
let input_and_models_map =
Incr_map.merge map_input model ~f:(fun ~key:_ -> function
| `Left input -> Some (input, model_info.default)
| `Right _ -> None
| `Both input_and_models -> Some input_and_models)
in
let module Cmp = (val key_comparator) in
let create_keyed =
unstage (Path.Elem.keyed ~compare:Cmp.comparator.compare key_id)
in
let results_map, input_map, lifecycle_map =
unzip3_mapi' input_and_models_map ~f:(fun ~key ~data:input_and_model ->
annotate Model_and_input input_and_model;
let path = Path.append path Path.Elem.(Assoc (create_keyed key)) in
let%pattern_bind value, model = input_and_model in
let key_incr = Incr.const key in
annotate Assoc_key key_incr;
annotate Assoc_input value;
let environment =
environment
|> Environment.add_exn ~key:key_id ~data:key_incr
|> Environment.add_exn ~key:data_id ~data:value
in
let inject_dynamic action = inject_dynamic (key, action) in
let inject_static action = inject_static (key, action) in
let snapshot =
run ~environment ~path ~clock ~inject_dynamic ~inject_static ~model
in
( Snapshot.result snapshot
, Input.to_incremental (Snapshot.input snapshot)
, Snapshot.lifecycle_or_empty snapshot ))
in
annotate Assoc_results results_map;
annotate Assoc_lifecycles lifecycle_map;
annotate Assoc_inputs input_map;
let lifecycle =
Incr_map.unordered_fold_nested_maps
lifecycle_map
~init:Path.Map.empty
~add:(fun ~outer_key:_ ~inner_key:key ~data acc ->
Map.update acc key ~f:(function
| Some _ -> raise_duplicate_path key
| None -> data))
~remove:(fun ~outer_key:_ ~inner_key:key ~data:_ acc -> Map.remove acc key)
in
annotate Assoc_lifecycles lifecycle;
Snapshot.create
~result:results_map
~input:(Input.dynamic input_map)
~lifecycle:(Some lifecycle)
in
let apply_static ~inject_dynamic ~inject_static ~schedule_event model (id, action) =
let inject_dynamic a = inject_dynamic (id, a) in
let inject_static a = inject_static (id, a) in
let specific_model =
Map.find model id |> Option.value ~default:model_info.default
in
let data =
apply_static ~inject_dynamic ~inject_static ~schedule_event specific_model action
in
if model_info.equal data model_info.default
then Map.remove model id
else Map.set model ~key:id ~data
in
let apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
model
(id, action)
=
let input = Option.bind input ~f:(fun input -> Map.find input id) in
let inject_dynamic a = inject_dynamic (id, a) in
let inject_static a = inject_static (id, a) in
let specific_model =
Map.find model id |> Option.value ~default:model_info.default
in
let data =
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
specific_model
action
in
if model_info.equal data model_info.default
then Map.remove model id
else Map.set model ~key:id ~data
in
let reset ~inject_dynamic ~inject_static ~schedule_event model =
Map.filter_mapi model ~f:(fun ~key:id ~data ->
let inject_dynamic a = inject_dynamic (id, a) in
let inject_static a = inject_static (id, a) in
let new_model = reset ~inject_dynamic ~inject_static ~schedule_event data in
if model_info.equal new_model model_info.default then None else Some new_model)
in
T
{ model = Meta.Model.map key_comparator key_id cmp_id model_info
; input = Meta.Input.map key_id cmp_id input_info
; dynamic_action = Meta.Action.map key_id dynamic_action
; static_action = Meta.Action.map key_id static_action
; apply_static
; apply_dynamic
; reset
; run
}
| Assoc_on
{ map
; io_comparator
; model_comparator
; io_key_id
; io_cmp_id
; model_key_id
; model_cmp_id
; data_id
; by
; get_model_key
} ->
let module Model_comparator = (val model_comparator) in
let module Io_comparator = (val io_comparator) in
let model_key_comparator = Model_comparator.comparator in
let (T
{ model = model_info
; input = input_info
; dynamic_action
; static_action
; apply_static
; apply_dynamic
; run
; reset
})
=
gather by
in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let map_input = Value.eval environment map in
let model_lookup = Incr_map.Lookup.create model ~comparator:model_key_comparator in
let create_keyed =
unstage (Path.Elem.keyed ~compare:Io_comparator.comparator.compare io_key_id)
in
let results_map, input_map, lifecycle_map =
unzip3_mapi' map_input ~f:(fun ~key ~data:value ->
let%pattern_bind results_map, input_map, lifecycle_map =
let path = Path.append path Path.Elem.(Assoc (create_keyed key)) in
let key_incr = Incr.const key in
annotate Assoc_key key_incr;
annotate Assoc_input value;
let environment =
environment
|> Environment.add_exn ~key:io_key_id ~data:key_incr
|> Environment.add_exn ~key:data_id ~data:value
in
let model_key =
let%map value = value in
get_model_key key value
in
Incr.set_cutoff
model_key
(Incr.Cutoff.of_compare model_key_comparator.compare);
let%bind model_key = model_key in
let inject_dynamic action = inject_dynamic (key, model_key, action) in
let inject_static action = inject_static (key, model_key, action) in
let model =
match%map Incr_map.Lookup.find model_lookup model_key with
| None -> model_info.default
| Some (_prev_io_key, model) -> model
in
let snapshot =
run ~environment ~path ~clock ~inject_dynamic ~inject_static ~model
in
let%mapn result = Snapshot.result snapshot
and input = Input.to_incremental (Snapshot.input snapshot)
and lifecycle = Snapshot.lifecycle_or_empty snapshot in
result, input, lifecycle
in
results_map, input_map, lifecycle_map)
in
annotate Assoc_results results_map;
annotate Assoc_lifecycles lifecycle_map;
let lifecycle =
Incr_map.unordered_fold_nested_maps
lifecycle_map
~init:Path.Map.empty
~add:(fun ~outer_key:_ ~inner_key:key ~data acc ->
Map.update acc key ~f:(function
| Some _ -> raise_duplicate_path key
| None -> data))
~remove:(fun ~outer_key:_ ~inner_key:key ~data:_ acc -> Map.remove acc key)
in
annotate Assoc_lifecycles lifecycle;
Snapshot.create
~result:results_map
~input:(Input.dynamic input_map)
~lifecycle:(Some lifecycle)
in
let apply_static
~inject_dynamic
~inject_static
~schedule_event
model
(input_id, model_id, action)
=
let inject_dynamic a = inject_dynamic (input_id, model_id, a) in
let inject_static a = inject_static (input_id, model_id, a) in
let specific_model =
match Map.find model model_id with
| None -> model_info.default
| Some (_prev_io_key, model) -> model
in
let new_model =
apply_static ~inject_dynamic ~inject_static ~schedule_event specific_model action
in
if model_info.equal new_model model_info.default
then Map.remove model model_id
else Map.set model ~key:model_id ~data:(input_id, new_model)
in
let apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
model
(input_id, model_id, action)
=
let input = Option.bind input ~f:(fun input -> Map.find input input_id) in
let inject_dynamic a = inject_dynamic (input_id, model_id, a) in
let inject_static a = inject_static (input_id, model_id, a) in
let specific_model =
match Map.find model model_id with
| None -> model_info.default
| Some (_prev_io_key, model) -> model
in
let new_model =
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
specific_model
action
in
if model_info.equal new_model model_info.default
then Map.remove model model_id
else Map.set model ~key:model_id ~data:(input_id, new_model)
in
let reset ~inject_dynamic ~inject_static ~schedule_event model =
Map.filter_mapi model ~f:(fun ~key:model_id ~data:(input_id, model) ->
let inject_dynamic a = inject_dynamic (input_id, model_id, a) in
let inject_static a = inject_static (input_id, model_id, a) in
let new_model = reset ~inject_dynamic ~inject_static ~schedule_event model in
if model_info.equal new_model model_info.default
then None
else Some (input_id, new_model))
in
T
{ model =
Meta.Model.map_on
model_comparator
io_comparator
model_key_id
io_key_id
model_cmp_id
model_info
; input = Meta.Input.map io_key_id io_cmp_id input_info
; dynamic_action =
Meta.Action.map_for_assoc_on io_key_id model_key_id dynamic_action
; static_action = Meta.Action.map_for_assoc_on io_key_id model_key_id static_action
; apply_static
; apply_dynamic
; reset
; run
}
| Assoc_simpl { map; by } ->
let run ~environment ~path ~clock:_ ~model:_ ~inject_dynamic:_ ~inject_static:_ =
let map_input = Value.eval environment map in
let result = Incr_map.mapi map_input ~f:(fun ~key ~data -> by path key data) in
Snapshot.create ~result ~input:Input.static ~lifecycle:None
in
T
{ model = Meta.Model.unit
; input = Meta.Input.unit
; dynamic_action = Meta.Action.nothing
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset = reset_unit_model
; run
}
| Switch { match_; arms; here = _ } ->
let gathered = Map.map arms ~f:gather in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let index = Value.eval environment match_ in
let%pattern_bind result, input, lifecycle =
let%bind index = index in
let path = Path.append path (Path.Elem.Switch index) in
let (T
{ model = model_info
; input = input_info
; dynamic_action = dynamic_action_info
; static_action = static_action_info
; apply_static = _
; apply_dynamic = _
; reset = _
; run
})
=
Map.find_exn gathered index
in
let chosen_model =
Incremental.map model ~f:(fun map ->
let (Meta.Model.Hidden.T { model; info; t_of_sexp = _ }) =
Meta.Multi_model.find_exn map index
in
let equal =
Meta.Model.Type_id.same_witness_exn info.type_id model_info.type_id
in
Type_equal.conv equal model)
in
let inject_dynamic action =
inject_dynamic
(Meta.Action.Hidden.T { action; type_id = dynamic_action_info; key = index })
in
let inject_static action =
inject_static
(Meta.Action.Hidden.T { action; type_id = static_action_info; key = index })
in
let snapshot =
run ~environment ~model:chosen_model ~path ~clock ~inject_dynamic ~inject_static
in
let input =
let%mapn input = Input.to_incremental (Snapshot.input snapshot) in
Meta.Input.Hidden.T { input; type_id = input_info; key = index }
in
let%mapn result = Snapshot.result snapshot
and lifecycle = Snapshot.lifecycle_or_empty snapshot
and input = input in
result, input, lifecycle
in
let input = Input.dynamic input in
Snapshot.create ~result ~input ~lifecycle:(Some lifecycle)
in
let apply_static
~inject_dynamic
~inject_static
~schedule_event
model
(action : int Meta.Action.Hidden.t)
=
let (T { action; type_id = action_type_id; key = index }) = action in
let (T { model = chosen_model; info = chosen_model_info; _ }) =
Meta.Multi_model.find_exn model index
in
let inject_static action =
inject_static
(Meta.Action.Hidden.T { action; type_id = action_type_id; key = index })
in
let (T
{ model = tm
; input = _
; static_action = am
; dynamic_action = dm
; apply_static
; apply_dynamic = _
; run = _
; reset = _
})
=
Map.find_exn gathered index
in
let T = Meta.Model.Type_id.same_witness_exn tm.type_id chosen_model_info.type_id in
let T = Meta.Action.Type_id.same_witness_exn am action_type_id in
let inject_dynamic action =
inject_dynamic (Meta.Action.Hidden.T { action; type_id = dm; key = index })
in
let new_model =
apply_static ~inject_dynamic ~inject_static ~schedule_event chosen_model action
in
let new_model = Meta.Model.Hidden.create tm new_model in
Meta.Multi_model.set model ~key:index ~data:new_model
in
let apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
model
(Meta.Action.Hidden.T { action; type_id = action_type_id; key = index })
=
let (T
{ model = tm
; input = im
; static_action = am
; dynamic_action = dm
; apply_static = _
; apply_dynamic
; run = _
; reset = _
})
=
Map.find_exn gathered index
in
let (T { model = chosen_model; info = chosen_model_info; _ }) =
Meta.Multi_model.find_exn model index
in
match
( Meta.Action.Type_id.same_witness action_type_id dm
, Meta.Model.Type_id.same_witness chosen_model_info.type_id tm.type_id )
with
| Some T, Some T ->
let inject_static action =
inject_static (Meta.Action.Hidden.T { action; type_id = am; key = index })
in
let inject_dynamic action =
inject_dynamic (Meta.Action.Hidden.T { action; type_id = dm; key = index })
in
let new_model =
match input with
| Some
(Meta.Input.Hidden.T
{ input = chosen_input; type_id = chosen_input_info; key = index' }) ->
(match index = index', Meta.Input.same_witness chosen_input_info im with
| true, Some T ->
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
(Some chosen_input)
chosen_model
action
| _ ->
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
None
chosen_model
action)
| None ->
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
None
chosen_model
action
in
let new_model = Meta.Model.Hidden.create tm new_model in
Meta.Multi_model.set model ~key:index ~data:new_model
| None, None | Some T, None | None, Some T ->
let action = Meta.Action.Type_id.to_sexp action_type_id action in
eprint_s
[%message
"an action inside of Bonsai.switch has been dropped because the computation \
is no longer active"
(index : int)
(action : Sexp.t)];
model
in
let reset ~inject_dynamic ~inject_static ~schedule_event model =
let f ~key:index ~data:(model : Meta.Model.Hidden.t) =
let (T { model = chosen_model; info = chosen_model_info; _ }) = model in
let (T
{ model = tm
; input = _
; static_action = am
; dynamic_action = dm
; reset
; apply_static = _
; apply_dynamic = _
; run = _
})
=
Map.find_exn gathered index
in
let inject_static action =
inject_static (Meta.Action.Hidden.T { action; type_id = am; key = index })
in
let inject_dynamic action =
inject_dynamic (Meta.Action.Hidden.T { action; type_id = dm; key = index })
in
let T =
Meta.Model.Type_id.same_witness_exn tm.type_id chosen_model_info.type_id
in
let new_model =
reset ~inject_dynamic ~inject_static ~schedule_event chosen_model
in
Meta.Model.Hidden.create tm new_model
in
Meta.Multi_model.of_models (Map.mapi (Meta.Multi_model.to_models model) ~f)
in
let model =
let models =
Map.map gathered ~f:(fun (T { model; _ }) ->
Meta.Model.Hidden.create model model.default)
in
Meta.Multi_model.model_info (Meta.Multi_model.of_models models)
in
T
{ model
; input = Meta.Input.Hidden.int
; dynamic_action = Meta.Action.Hidden.int
; static_action = Meta.Action.Hidden.int
; apply_static
; apply_dynamic
; reset
; run
}
| Lazy lazy_computation ->
let dynamic_action = Meta.Action.Hidden.unit in
let static_action = Meta.Action.Hidden.unit in
let model = Meta.Model.Hidden.lazy_ in
let gathered = Lazy.map lazy_computation ~f:gather in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let (T
{ model = model_info
; input = input_info
; dynamic_action = dynamic_action_info
; static_action = static_action_info
; run
; _
})
=
force gathered
in
let input_model =
let%map model = model in
let (Meta.Model.Hidden.T { model; info; _ }) =
Option.value
model
~default:(Meta.Model.Hidden.create model_info model_info.default)
in
let witness =
Meta.Model.Type_id.same_witness_exn info.type_id model_info.type_id
in
Type_equal.conv witness model
in
let inject_dynamic action =
inject_dynamic
(Meta.Action.Hidden.T { action; type_id = dynamic_action_info; key = () })
in
let inject_static action =
inject_static
(Meta.Action.Hidden.T { action; type_id = static_action_info; key = () })
in
let snapshot =
run ~environment ~path ~clock ~model:input_model ~inject_dynamic ~inject_static
in
let input =
Input.map (Snapshot.input snapshot) ~f:(fun input ->
Meta.Input.Hidden.T { input; type_id = input_info; key = () })
in
Snapshot.create
~input
~result:(Snapshot.result snapshot)
~lifecycle:(Snapshot.lifecycle snapshot)
in
let apply_static ~inject_dynamic ~inject_static ~schedule_event model action =
let (T
{ model = model_info
; dynamic_action = dynamic_action_info
; static_action = static_action_info
; apply_static
; _
})
=
force gathered
in
let inject_dynamic action =
inject_dynamic
(Meta.Action.Hidden.T { action; type_id = dynamic_action_info; key = () })
in
let inject_static action =
inject_static
(Meta.Action.Hidden.T { action; type_id = static_action_info; key = () })
in
let (Meta.Action.Hidden.T { action; type_id = action_type_id; key = () }) =
action
in
let (Meta.Model.Hidden.T { model = chosen_model; info = chosen_model_info; _ }) =
Option.value
model
~default:(Meta.Model.Hidden.create model_info model_info.default)
in
let T = Meta.Action.Type_id.same_witness_exn action_type_id static_action_info in
let T =
Meta.Model.Type_id.same_witness_exn chosen_model_info.type_id model_info.type_id
in
let new_model =
apply_static ~inject_dynamic ~inject_static ~schedule_event chosen_model action
in
Some (Meta.Model.Hidden.create model_info new_model)
in
let apply_dynamic ~inject_dynamic ~inject_static ~schedule_event input model action =
let (T
{ model = model_info
; input = input_info
; dynamic_action = dynamic_action_info
; static_action = static_action_info
; apply_dynamic
; _
})
=
force gathered
in
let inject_dynamic action =
inject_dynamic
(Meta.Action.Hidden.T { action; type_id = dynamic_action_info; key = () })
in
let inject_static action =
inject_static
(Meta.Action.Hidden.T { action; type_id = static_action_info; key = () })
in
let (Meta.Action.Hidden.T { action; type_id = action_type_id; key = () }) =
action
in
let (Meta.Model.Hidden.T { model = chosen_model; info = chosen_model_info; _ }) =
Option.value
model
~default:(Meta.Model.Hidden.create model_info model_info.default)
in
let T = Meta.Action.Type_id.same_witness_exn action_type_id dynamic_action_info in
let T =
Meta.Model.Type_id.same_witness_exn chosen_model_info.type_id model_info.type_id
in
let new_model =
match input with
| Some (Meta.Input.Hidden.T { input; type_id = input_type_id; key = () }) ->
let T = Meta.Input.same_witness_exn input_type_id input_info in
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
(Some input)
chosen_model
action
| None ->
apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
None
chosen_model
action
in
Some (Meta.Model.Hidden.create model_info new_model)
in
let reset' ~inject_dynamic ~inject_static ~schedule_event model =
let (T
{ model = model_info
; dynamic_action = dynamic_action_info
; static_action = static_action_info
; reset
; _
})
=
force gathered
in
let inject_dynamic action =
inject_dynamic
(Meta.Action.Hidden.T { action; type_id = dynamic_action_info; key = () })
in
let inject_static action =
inject_static
(Meta.Action.Hidden.T { action; type_id = static_action_info; key = () })
in
let (Meta.Model.Hidden.T { model = chosen_model; info = chosen_model_info; _ }) =
model
in
let T =
Meta.Model.Type_id.same_witness_exn chosen_model_info.type_id model_info.type_id
in
let new_model = reset ~inject_dynamic ~inject_static ~schedule_event chosen_model in
Meta.Model.Hidden.create model_info new_model
in
let reset ~inject_dynamic ~inject_static ~schedule_event model =
match model with
| None -> None
| Some model -> Some (reset' ~inject_dynamic ~inject_static ~schedule_event model)
in
T
{ model
; input = Meta.Input.Hidden.unit
; dynamic_action
; static_action
; apply_static
; apply_dynamic
; run
; reset
}
| Wrap
{ wrapper_model
; action_id
; result_id
; inject_id
; model_id
; inner
; dynamic_apply_action
; reset = reset_me
} ->
let (T
{ model = inner_model
; input = inner_input
; dynamic_action = inner_dynamic_action
; static_action = inner_static_action
; apply_static
; apply_dynamic
; run
; reset
})
=
gather inner
in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let%pattern_bind outer_model, inner_model = model in
let dynamic_inject_outer a = inject_dynamic (Either.First a) in
let dynamic_inject_inner a = inject_dynamic (Either.Second a) in
let inner_snapshot =
let environment =
environment
|> Environment.add_exn ~key:model_id ~data:outer_model
|> Environment.add_exn ~key:inject_id ~data:(Incr.return dynamic_inject_outer)
in
run
~environment
~path
~model:inner_model
~clock
~inject_dynamic:dynamic_inject_inner
~inject_static
in
let inner_result = Snapshot.result inner_snapshot in
let input =
Input.merge
(Snapshot.input inner_snapshot)
(Input.dynamic (Snapshot.result inner_snapshot))
in
Snapshot.create
~result:inner_result
~input
~lifecycle:(Snapshot.lifecycle inner_snapshot)
in
let dynamic_action = Meta.Action.both action_id inner_dynamic_action in
let model = Meta.Model.both wrapper_model inner_model in
let apply_static ~inject_dynamic ~inject_static ~schedule_event (m1, m2) action =
let inject_dynamic a = inject_dynamic (Second a) in
m1, apply_static ~inject_dynamic ~inject_static ~schedule_event m2 action
in
let apply_dynamic
~inject_dynamic
~inject_static
~schedule_event
input
(outer_model, inner_model)
action
=
let dynamic_inject_outer a = inject_dynamic (Either.First a) in
let dynamic_inject_inner a = inject_dynamic (Either.Second a) in
match action with
| First action_outer ->
let new_outer_model =
dynamic_apply_action
~inject_dynamic:dynamic_inject_outer
~inject_static:Nothing.unreachable_code
~schedule_event
(Option.map input ~f:snd)
outer_model
action_outer
in
new_outer_model, inner_model
| Second action_inner ->
let new_inner_model =
apply_dynamic
~inject_dynamic:dynamic_inject_inner
~inject_static
~schedule_event
(Option.map input ~f:fst)
inner_model
action_inner
in
outer_model, new_inner_model
in
let reset ~inject_dynamic ~inject_static ~schedule_event (outer_model, inner_model) =
let outer_model =
let inject_dynamic a = inject_dynamic (First a) in
reset_me
~inject_dynamic
~inject_static:Nothing.unreachable_code
~schedule_event
outer_model
in
let inner_model =
let inject_dynamic a = inject_dynamic (Second a) in
reset ~inject_dynamic ~inject_static ~schedule_event inner_model
in
outer_model, inner_model
in
T
{ model
; input = Meta.Input.both inner_input result_id
; dynamic_action
; static_action = inner_static_action
; apply_static
; apply_dynamic
; run
; reset
}
| With_model_resetter { inner; reset_id } ->
let (T
{ model
; input
; dynamic_action
; static_action
; apply_static
; apply_dynamic
; run
; reset
})
=
gather inner
in
let run ~environment ~path ~clock ~model ~inject_dynamic ~inject_static =
let reset_event = inject_static (First ()) in
let inject_static a = inject_static (Second a) in
let environment =
environment |> Environment.add_exn ~key:reset_id ~data:(Incr.return reset_event)
in
let snapshot =
run ~environment ~path ~model ~clock ~inject_dynamic ~inject_static
in
let result = Snapshot.result snapshot in
Snapshot.create
~result
~input:(Snapshot.input snapshot)
~lifecycle:(Snapshot.lifecycle snapshot)
in
let static_action = Meta.(Action.both Action.Type_id.unit static_action) in
let apply_static ~inject_dynamic ~inject_static ~schedule_event m =
let inject_static a = inject_static (Second a) in
function
| First () -> reset ~inject_dynamic ~inject_static ~schedule_event m
| Second a -> apply_static ~inject_dynamic ~inject_static ~schedule_event m a
in
let apply_dynamic ~inject_dynamic ~inject_static ~schedule_event i m =
let inject_static a = inject_static (Second a) in
apply_dynamic ~inject_dynamic ~inject_static ~schedule_event i m
in
let reset ~inject_dynamic ~inject_static ~schedule_event m =
let inject_static a = inject_static (Second a) in
reset ~inject_dynamic ~inject_static ~schedule_event m
in
T
{ model
; input
; static_action
; dynamic_action
; apply_static
; apply_dynamic
; run
; reset
}
| Path ->
let run ~environment:_ ~path ~clock:_ ~model:_ ~inject_dynamic:_ ~inject_static:_ =
let result = Incr.return path in
annotate Path result;
Snapshot.create ~result ~input:Input.static ~lifecycle:None
in
T
{ model = Meta.Model.unit
; input = Meta.Input.unit
; dynamic_action = Meta.Action.nothing
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset = reset_unit_model
; run
}
| Lifecycle lifecycle ->
let run ~environment ~path ~clock:_ ~model:_ ~inject_dynamic:_ ~inject_static:_ =
let lifecycle =
match%pattern_bind Value.eval environment lifecycle with
| Some lifecycle ->
let%map lifecycle = lifecycle in
Path.Map.singleton path lifecycle
| None -> do_nothing_lifecycle
in
Snapshot.create
~result:(Incr.return ())
~input:Input.static
~lifecycle:(Some lifecycle)
in
T
{ model = Meta.Model.unit
; input = Meta.Input.unit
; dynamic_action = Meta.Action.nothing
; static_action = Meta.Action.nothing
; apply_static = unusable_static_apply_action
; apply_dynamic = unusable_dynamic_apply_action
; reset = reset_unit_model
; run
}
;;