package metapp

  1. Overview
  2. Docs
Legend:
Page
Library
Module
Module type
Parameter
Class
Class type
Source

Source file metapp_api.ml

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
module type UnaryS = sig
  type 'a t
end

module type UnaryMakeS = sig
  type 'a t

  val make : unit -> 'a t
end

module type MetapointsS = sig
  type 'a x

  type t = {
      expr : Ppxlib.expression x;
      pat : Ppxlib.pattern x;
      typ : Ppxlib.core_type x;
      class_type : Ppxlib.class_type x;
      class_type_field : Ppxlib.class_type_field x;
      class_expr : Ppxlib.class_expr x;
      class_field : Ppxlib.class_field x;
      module_type : Ppxlib.module_type x;
      module_expr : Ppxlib.module_expr x;
      signature_item : Ppxlib.signature_item x;
      structure_item : Ppxlib.structure_item x;
    }
end

module type QuotationsS = sig
  type 'a x

  type t = {
      expr : Ppxlib.expression x;
      pat : Ppxlib.pattern x;
      typ : Ppxlib.core_type x;
      signature : Ppxlib.signature x;
      signature_item : Ppxlib.signature_item x;
      structure : Ppxlib.structure x;
      structure_item : Ppxlib.structure_item x;
    }
end

module type MetapointS = sig
  include Metapp_preutils.ExtensibleS

  module MetapointAccessor (Collector : MetapointsS) : sig
    val get : Collector.t -> t Collector.x

    val set : t Collector.x -> Collector.t -> Collector.t
  end
end

module type QuotationS = sig
  include Metapp_preutils.VisitableS

  val of_payload : Ppxlib.payload -> t

  module QuotationAccessor (Collector : QuotationsS) : sig
    val get : Collector.t -> t Collector.x

    val set : t Collector.x -> Collector.t -> Collector.t
  end
end

module Exp = struct
  include Metapp_preutils.Exp

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.expr

    let set (x : t Collector.x) (c : Collector.t) =
      { c with expr = x }
  end

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.expr

    let set (x : t Collector.x) (c : Collector.t) =
      { c with expr = x }
  end
end

module Pat = struct
  include Metapp_preutils.Pat

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.pat

    let set (x : t Collector.x) (c : Collector.t) =
      { c with pat = x }
  end

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.pat

    let set (x : t Collector.x) (c : Collector.t) =
      { c with pat = x }
  end
end

module Typ = struct
  include Metapp_preutils.Typ

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.typ

    let set (x : t Collector.x) (c : Collector.t) =
      { c with typ = x }
  end

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.typ

    let set (x : t Collector.x) (c : Collector.t) =
      { c with typ = x }
  end
end

module Cty = struct
  include Metapp_preutils.Cty

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.class_type

    let set (x : t Collector.x) (c : Collector.t) =
      { c with class_type = x }
  end
end

module Ctf = struct
  include Metapp_preutils.Ctf

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.class_type_field

    let set (x : t Collector.x) (c : Collector.t) =
      { c with class_type_field = x }
  end
end

module Cl = struct
  include Metapp_preutils.Cl

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.class_expr

    let set (x : t Collector.x) (c : Collector.t) =
      { c with class_expr = x }
  end
end

module Cf = struct
  include Metapp_preutils.Cf

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.class_field

    let set (x : t Collector.x) (c : Collector.t) =
      { c with class_field = x }
  end
end

module Mty = struct
  include Metapp_preutils.Mty

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.module_type

    let set (x : t Collector.x) (c : Collector.t) =
      { c with module_type = x }
  end
end

module Mod = struct
  include Metapp_preutils.Mod

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.module_expr

    let set (x : t Collector.x) (c : Collector.t) =
      { c with module_expr = x }
  end
end

module Sig = struct
  include Metapp_preutils.Sig

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.signature

    let set (x : t Collector.x) (c : Collector.t) =
      { c with signature = x }
  end
end

module Sigi = struct
  include Metapp_preutils.Sigi

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.signature_item

    let set (x : t Collector.x) (c : Collector.t) =
      { c with signature_item = x }
  end

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.signature_item

    let set (x : t Collector.x) (c : Collector.t) =
      { c with signature_item = x }
  end
end

module Str = struct
  include Metapp_preutils.Str

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.structure

    let set (x : t Collector.x) (c : Collector.t) =
      { c with structure = x }
  end
end

module Stri = struct
  include Metapp_preutils.Stri

  module MetapointAccessor (Collector : MetapointsS) = struct
    let get (c : Collector.t) : t Collector.x = c.structure_item

    let set (x : t Collector.x) (c : Collector.t) =
      { c with structure_item = x }
  end

  module QuotationAccessor (Collector : QuotationsS) = struct
    let get (c : Collector.t) : t Collector.x = c.structure_item

    let set (x : t Collector.x) (c : Collector.t) =
      { c with structure_item = x }
  end
end

module type MetapointsMakeS = sig
  include MetapointsS

  module Make (X : UnaryMakeS with type 'a t = 'a x) : sig
    val make : unit -> t
  end
end

module type MetapointsWithMakeS = sig
  include MetapointsS

  val make : unit -> t
end

module type QuotationsMakeS = sig
  include QuotationsS

  module Make (X : UnaryMakeS with type 'a t = 'a x) : sig
    val make : unit -> t
  end
end

module type QuotationsWithMakeS = sig
  include QuotationsS

  val make : unit -> t
end

module Metapoints (X : UnaryS)
    : MetapointsMakeS with type 'a x = 'a X.t = struct
  module rec Sub : sig
    include MetapointsS with type 'a x = 'a X.t
  end = struct
    include Sub
  end

  include Sub

  module Make (X : UnaryMakeS with type 'a t = 'a X.t) = struct
    let make () = {
      expr = X.make ();
      pat = X.make ();
      typ = X.make ();
      class_type = X.make ();
      class_type_field = X.make ();
      class_expr = X.make ();
      class_field = X.make ();
      module_type = X.make ();
      module_expr = X.make ();
      signature_item = X.make ();
      structure_item = X.make ();
    }
  end
end

module Quotations (X : UnaryS)
    : QuotationsMakeS with type 'a x = 'a X.t = struct
  module rec Sub : sig
    include QuotationsS with type 'a x = 'a X.t
  end = struct
    include Sub
  end

  include Sub

  module Make (X : UnaryMakeS with type 'a t = 'a X.t) = struct
    let make () = {
      expr = X.make ();
      pat = X.make ();
      typ = X.make ();
      signature = X.make ();
      signature_item = X.make ();
      structure = X.make ();
      structure_item = X.make ();
    }
  end
end

module MetapointName = Metapoints (struct type 'a t = string end)

let metapoint_name : MetapointName.t =
  {
    expr = "expr";
    pat = "pat";
    typ = "typ";
    class_type = "class_type";
    class_type_field = "class_type_field";
    class_expr = "class_expr";
    class_field = "class_field";
    module_type = "module_type";
    module_expr = "module_expr";
    signature_item = "signature_item";
    structure_item = "structure_item";
  }

module QuotationName = Quotations (struct type 'a t = string end)

let quotation_name : QuotationName.t =
  {
    expr = "expr";
    pat = "pat";
    typ = "typ";
    signature = "signature";
    signature_item = "signature_item";
    structure = "structure";
    structure_item = "structure_item";
  }

module MetapointsWithMake (X : UnaryMakeS) : MetapointsWithMakeS
with type 'a x = 'a X.t = struct
  include Metapoints (X)

  include Make (X)
end

module QuotationsWithMake (X : UnaryMakeS) : QuotationsWithMakeS
with type 'a x = 'a X.t = struct
  include Quotations (X)

  include Make (X)
end

module type Map = sig
  type 'a x

  type 'a y

  val map : 'a x -> 'a y
end

module MetapointMap (X : MetapointsS) (Y : MetapointsS)
    (M : Map with type 'a x = 'a X.x and type 'a y = 'a Y.x) = struct
  let map (x : X.t) : Y.t = {
    expr = M.map x.expr;
    pat = M.map x.pat;
    typ = M.map x.typ;
    class_type = M.map x.class_type;
    class_type_field = M.map x.class_type_field;
    class_expr = M.map x.class_expr;
    class_field = M.map x.class_field;
    module_type = M.map x.module_type;
    module_expr = M.map x.module_expr;
    signature_item = M.map x.signature_item;
    structure_item = M.map x.structure_item;
  }
end

module QuotationMap (X : QuotationsS) (Y : QuotationsS)
    (M : Map with type 'a x = 'a X.x and type 'a y = 'a Y.x) = struct
  let map (x : X.t) : Y.t = {
    expr = M.map x.expr;
    pat = M.map x.pat;
    typ = M.map x.typ;
    signature = M.map x.signature;
    signature_item = M.map x.signature_item;
    structure = M.map x.structure;
    structure_item = M.map x.structure_item;
  }
end

module OptionArray = struct
  type 'a t = 'a option array
end

module OptionArrayMetapoints = Metapoints (OptionArray)

module LocationArray = struct
  type _ t = Location.t array
end

module MetapointsLocation = Metapoints (LocationArray)

module rec ArrayQuotation : sig
  type context = {
      metapoints : OptionArrayMetapoints.t;
      loc : MetapointsLocation.t;
      subquotations : ArrayQuotations.t;
    }

  type 'a quotation = {
      context : context;
      fill : unit -> 'a;
    }

  type 'a t = (unit -> 'a quotation) array
end = struct
  include ArrayQuotation
end
and ArrayQuotations : QuotationsS with type 'a x = 'a ArrayQuotation.t =
    Quotations (ArrayQuotation)

type context = ArrayQuotation.context

let top_context : context option ref =
  ref None
OCaml

Innovation. Community. Security.